# Copyright AllSeen Alliance. All rights reserved.
#
#    Permission to use, copy, modify, and/or distribute this software for any
#    purpose with or without fee is hereby granted, provided that the above
#    copyright notice and this permission notice appear in all copies.
#
#    THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
#    WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
#    MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
#    ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
#    WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
#    ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
#    OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.

import os

Import('env')

vars = Variables()
vars.Add(PathVariable('LIBXML2_INCLUDE',
                      'Directory containing libxml2 include files.',
                       os.environ.get('LIBXML2_INCLUDE','/usr/include/libxml2')))
vars.Add(PathVariable('LIBICONV_INCLUDE',
                      'Directory containing iconv include files.',
                       os.environ.get('LIBICONV_INCLUDE','/usr/include/')))
vars.Update(env)
Help(vars.GenerateHelpText(env))


env['_ALLJOYN_TIME_'] = True
env['OBJDIR_SERVICES_TIME'] = env['OBJDIR'] + '/services/time'

# Make config library and header file paths available to the global environment
env.Append(LIBPATH = '$DISTDIR/time/lib');
env.Append(CPPPATH = '$DISTDIR/time/inc');


if not env.has_key('_ALLJOYN_ABOUT_') and os.path.exists('../../../core/alljoyn/services/about/SConscript'):
    env.SConscript('../../../core/alljoyn/services/about/SConscript')

if not env.has_key('_ALLJOYN_SERVICES_COMMON_') and os.path.exists('../services_common/SConscript'):
    env.SConscript('../services_common/SConscript')

if 'cpp' in env['bindings'] and not env.has_key('_ALLJOYNCORE_') and os.path.exists('../../../core/alljoyn/alljoyn_core/SConscript'):
    env.SConscript('../../../core/alljoyn/alljoyn_core/SConscript')

if 'java' in env['bindings'] and not env.has_key('_ALLJOYN_JAVA_') and os.path.exists('../../../core/alljoyn/alljoyn_java/SConscript'):
    env.SConscript('../../../core/alljoyn/alljoyn_java/SConscript')

tsenv = env.Clone()

for b in tsenv['bindings']:
    if os.path.exists('%s/SConscript' % b):
        tsenv.VariantDir('$OBJDIR_SERVICES_TIME/%s' % b, b, duplicate = 0)

tsenv.SConscript(['$OBJDIR_SERVICES_TIME/%s/SConscript' % b for b in env['bindings'] if os.path.exists('%s/SConscript' % b) ],
                     exports = ['tsenv'])     
